init III

2024-10-14 00:08:40 +02:00
parent dbfba56f66
commit 1462d52e13
4572 changed files with 2658864 additions and 0 deletions
--- a/OTRS/Kernel/System/Log/File.pm
+++ b/OTRS/Kernel/System/Log/File.pm
@@ -0,0 +1,107 @@
+# --
+# Copyright (C) 2001-2019 OTRS AG, https://otrs.com/
+# --
+# This software comes with ABSOLUTELY NO WARRANTY. For details, see
+# the enclosed file COPYING for license information (GPL). If you
+# did not receive this file, see https://www.gnu.org/licenses/gpl-3.0.txt.
+# --
+
+## nofilter(TidyAll::Plugin::OTRS::Perl::Time)
+
+package Kernel::System::Log::File;
+
+use strict;
+use warnings;
+
+our @ObjectDependencies = (
+    'Kernel::Config',
+    'Kernel::System::Encode',
+);
+
+sub new {
+    my ( $Type, %Param ) = @_;
+
+    # allocate new hash for object
+    my $Self = {};
+    bless( $Self, $Type );
+
+    # get config object
+    my $ConfigObject = $Kernel::OM->Get('Kernel::Config');
+
+    # get logfile location
+    $Self->{LogFile} = $ConfigObject->Get('LogModule::LogFile')
+        || die 'Need LogModule::LogFile param in Config.pm';
+
+    # get log file suffix
+    if ( $ConfigObject->Get('LogModule::LogFile::Date') ) {
+        my ( $s, $m, $h, $D, $M, $Y, $WD, $YD, $DST ) = localtime( time() );    ## no critic
+        $Y = $Y + 1900;
+        $M = sprintf '%02d', ++$M;
+        $Self->{LogFile} .= ".$Y-$M";
+    }
+
+    # Fixed bug# 2265 - For IIS we need to create a own error log file.
+    # Bind stderr to log file, because iis do print stderr to web page.
+    if ( $ENV{SERVER_SOFTWARE} && $ENV{SERVER_SOFTWARE} =~ /^microsoft\-iis/i ) {
+        ## no critic
+        if ( !open STDERR, '>>', $Self->{LogFile} . '.error' ) {
+            ## use critic
+            print STDERR "ERROR: Can't write $Self->{LogFile}.error: $!";
+        }
+    }
+
+    return $Self;
+}
+
+sub Log {
+    my ( $Self, %Param ) = @_;
+
+    my $FH;
+
+    # open logfile
+    ## no critic
+    if ( !open $FH, '>>', $Self->{LogFile} ) {
+        ## use critic
+
+        # print error screen
+        print STDERR "\n";
+        print STDERR " >> Can't write $Self->{LogFile}: $! <<\n";
+        print STDERR "\n";
+        return;
+    }
+
+    # write log file
+    $Kernel::OM->Get('Kernel::System::Encode')->ConfigureOutputFileHandle( FileHandle => $FH );
+
+    print $FH '[' . localtime() . ']';    ## no critic
+
+    if ( lc $Param{Priority} eq 'debug' ) {
+        print $FH "[Debug][$Param{Module}][$Param{Line}] $Param{Message}\n";
+    }
+    elsif ( lc $Param{Priority} eq 'info' ) {
+        print $FH "[Info][$Param{Module}] $Param{Message}\n";
+    }
+    elsif ( lc $Param{Priority} eq 'notice' ) {
+        print $FH "[Notice][$Param{Module}] $Param{Message}\n";
+    }
+    elsif ( lc $Param{Priority} eq 'error' ) {
+        print $FH "[Error][$Param{Module}][$Param{Line}] $Param{Message}\n";
+    }
+    else {
+
+        # print error messages to STDERR
+        print STDERR
+            "[Error][$Param{Module}] Priority: '$Param{Priority}' not defined! Message: $Param{Message}\n";
+
+        # and of course to logfile
+        print $FH
+            "[Error][$Param{Module}] Priority: '$Param{Priority}' not defined! Message: $Param{Message}\n";
+    }
+
+    # close file handle
+    close $FH;
+
+    return 1;
+}
+
+1;
--- a/OTRS/Kernel/System/Log/SysLog.pm
+++ b/OTRS/Kernel/System/Log/SysLog.pm
@@ -0,0 +1,86 @@
+# --
+# Copyright (C) 2001-2019 OTRS AG, https://otrs.com/
+# --
+# This software comes with ABSOLUTELY NO WARRANTY. For details, see
+# the enclosed file COPYING for license information (GPL). If you
+# did not receive this file, see https://www.gnu.org/licenses/gpl-3.0.txt.
+# --
+
+package Kernel::System::Log::SysLog;
+
+use strict;
+use warnings;
+
+use Sys::Syslog qw();
+
+our @ObjectDependencies = (
+    'Kernel::Config',
+    'Kernel::System::Encode',
+);
+
+sub new {
+    my ( $Type, %Param ) = @_;
+
+    # allocate new hash for object
+    my $Self = {};
+    bless( $Self, $Type );
+
+    # set syslog facility
+    $Self->{SysLogFacility} = $Kernel::OM->Get('Kernel::Config')->Get('LogModule::SysLog::Facility') || 'user';
+
+    return $Self;
+}
+
+sub Log {
+    my ( $Self, %Param ) = @_;
+
+    # get needed objects
+    my $ConfigObject = $Kernel::OM->Get('Kernel::Config');
+    my $EncodeObject = $Kernel::OM->Get('Kernel::System::Encode');
+
+    # prepare data for byte output
+    if ( $ConfigObject->Get('LogModule::SysLog::Charset') =~ m/^utf-?8$/ ) {
+        $EncodeObject->EncodeOutput( \$Param{Message} );
+    }
+    else {
+        $Param{Message} = $EncodeObject->Convert(
+            Text  => $Param{Message},
+            From  => 'utf8',
+            To    => $ConfigObject->Get('LogModule::SysLog::Charset') || 'iso-8859-15',
+            Force => 1,
+        );
+    }
+
+    Sys::Syslog::openlog( $Param{LogPrefix}, 'cons,pid', $Self->{SysLogFacility} );
+
+    if ( lc $Param{Priority} eq 'debug' ) {
+        Sys::Syslog::syslog( 'debug', "[Debug][$Param{Module}][$Param{Line}] $Param{Message}" );
+    }
+    elsif ( lc $Param{Priority} eq 'info' ) {
+        Sys::Syslog::syslog( 'info', "[Info][$Param{Module}] $Param{Message}" );
+    }
+    elsif ( lc $Param{Priority} eq 'notice' ) {
+        Sys::Syslog::syslog( 'notice', "[Notice][$Param{Module}] $Param{Message}" );
+    }
+    elsif ( lc $Param{Priority} eq 'error' ) {
+        Sys::Syslog::syslog( 'err', "[Error][$Param{Module}][Line:$Param{Line}]: $Param{Message}" );
+    }
+    else {
+
+        # print error messages to STDERR
+        print STDERR
+            "[Error][$Param{Module}] Priority: '$Param{Priority}' not defined! Message: $Param{Message}\n";
+
+        # and of course to syslog
+        Sys::Syslog::syslog(
+            'err',
+            "[Error][$Param{Module}] Priority: '$Param{Priority}' not defined! Message: $Param{Message}"
+        );
+    }
+
+    Sys::Syslog::closelog();
+
+    return;
+}
+
+1;