init III

2024-10-14 00:08:40 +02:00
parent dbfba56f66
commit 1462d52e13
4572 changed files with 2658864 additions and 0 deletions
--- a/OTRS/Kernel/System/CustomerUser/Event/TicketUpdate.pm
+++ b/OTRS/Kernel/System/CustomerUser/Event/TicketUpdate.pm
@@ -0,0 +1,86 @@
+# --
+# Copyright (C) 2001-2019 OTRS AG, https://otrs.com/
+# --
+# This software comes with ABSOLUTELY NO WARRANTY. For details, see
+# the enclosed file COPYING for license information (GPL). If you
+# did not receive this file, see https://www.gnu.org/licenses/gpl-3.0.txt.
+# --
+
+package Kernel::System::CustomerUser::Event::TicketUpdate;
+
+use strict;
+use warnings;
+
+our @ObjectDependencies = (
+    'Kernel::System::Log',
+    'Kernel::System::Ticket',
+);
+
+sub new {
+    my ( $Type, %Param ) = @_;
+
+    # allocate new hash for object
+    my $Self = {};
+    bless( $Self, $Type );
+
+    return $Self;
+}
+
+sub Run {
+    my ( $Self, %Param ) = @_;
+
+    # check needed stuff
+    for (qw( Data Event Config UserID )) {
+        if ( !$Param{$_} ) {
+            $Kernel::OM->Get('Kernel::System::Log')->Log(
+                Priority => 'error',
+                Message  => "Need $_!"
+            );
+            return;
+        }
+    }
+    for (qw( UserLogin NewData OldData )) {
+        if ( !$Param{Data}->{$_} ) {
+            $Kernel::OM->Get('Kernel::System::Log')->Log(
+                Priority => 'error',
+                Message  => "Need $_ in Data!"
+            );
+            return;
+        }
+    }
+
+    # only update if fields have really changed
+    if (
+        $Param{Data}->{OldData}->{UserCustomerID} ne $Param{Data}->{NewData}->{UserCustomerID}
+        || $Param{Data}->{OldData}->{UserLogin} ne $Param{Data}->{NewData}->{UserLogin}
+        )
+    {
+
+        # get ticket object
+        my $TicketObject = $Kernel::OM->Get('Kernel::System::Ticket');
+
+        # perform search
+        my @Tickets = $TicketObject->TicketSearch(
+            Result               => 'ARRAY',
+            Limit                => 100_000,
+            CustomerUserLoginRaw => $Param{Data}->{OldData}->{UserLogin},
+            CustomerIDRaw        => $Param{Data}->{OldData}->{UserCustomerID},
+            ArchiveFlags         => [ 'y', 'n' ],
+            UserID               => 1,
+        );
+
+        # update the customer ID and login of tickets
+        for my $TicketID (@Tickets) {
+            $TicketObject->TicketCustomerSet(
+                No       => $Param{Data}->{NewData}->{UserCustomerID},
+                User     => $Param{Data}->{NewData}->{UserLogin},
+                TicketID => $TicketID,
+                UserID   => $Param{UserID},
+            );
+        }
+    }
+
+    return 1;
+}
+
+1;