init III

Perl OTRS/Kernel/Output/HTML/TicketZoom/Agent/Base.pm

@@ -0,0 +1,341 @@
+# --
+# Copyright (C) 2001-2019 OTRS AG, https://otrs.com/
+# --
+# This software comes with ABSOLUTELY NO WARRANTY. For details, see
+# the enclosed file COPYING for license information (GPL). If you
+# did not receive this file, see https://www.gnu.org/licenses/gpl-3.0.txt.
+# --
+
+package Kernel::Output::HTML::TicketZoom::Agent::Base;
+
+use strict;
+use warnings;
+
+use Digest::MD5 qw(md5_hex);
+
+use Kernel::System::VariableCheck qw(IsHashRefWithData);
+
+our @ObjectDependencies = (
+    'Kernel::Config',
+    'Kernel::Output::HTML::Layout',
+    'Kernel::System::DynamicField',
+    'Kernel::System::DynamicField::Backend',
+    'Kernel::System::Log',
+    'Kernel::System::SystemAddress',
+    'Kernel::System::Ticket::Article',
+    'Kernel::System::User',
+);
+
+sub new {
+    my ( $Type, %Param ) = @_;
+
+    # allocate new hash for object
+    my $Self = {};
+    bless( $Self, $Type );
+
+    return $Self;
+}
+
+=head2 ArticleRender()
+
+Returns article html.
+
+    my $HTML = $ArticleBaseObject->ArticleRender(
+        TicketID               => 123,         # (required)
+        ArticleID              => 123,         # (required)
+        ShowBrowserLinkMessage => 1,           # (optional) Default: 0.
+        ArticleActions         => [],          # (optional)
+    );
+
+Result:
+    $HTML = "<div>...</div>";
+
+=cut
+
+sub ArticleRender {
+    die 'Virtual method in base class must not be called.';
+}
+
+=head2 ArticleMetaFields()
+
+Returns common fields for any article.
+
+    my %ArticleMetaFields = $ArticleBaseObject->ArticleMetaFields(
+        TicketID  => 123,   # (required)
+        ArticleID => 123,   # (required)
+    );
+
+Returns:
+
+    %ArticleMetaFields = (
+        DynamicField_Item => {
+            Label => 'Item',            # mandatory
+            Value => 'Value',           # mandatory
+            Link => 'http://...',       # optional
+        },
+        AccountedTime => {
+            ...
+        },
+    );
+
+=cut
+
+sub ArticleMetaFields {
+    my ( $Self, %Param ) = @_;
+
+    # Check needed stuff.
+    for my $Needed (qw(TicketID ArticleID)) {
+        if ( !$Param{$Needed} ) {
+            $Kernel::OM->Get('Kernel::System::Log')->Log(
+                Priority => 'error',
+                Message  => "Need $Needed!",
+            );
+            return;
+        }
+    }
+
+    my $ConfigObject  = $Kernel::OM->Get('Kernel::Config');
+    my $ArticleObject = $Kernel::OM->Get('Kernel::System::Ticket::Article');
+    my $LayoutObject  = $Kernel::OM->Get('Kernel::Output::HTML::Layout');
+
+    my %Result;
+
+    # show accounted article time
+    if (
+        $ConfigObject->Get('Ticket::ZoomTimeDisplay')
+        && $ConfigObject->Get('Ticket::Frontend::AccountTime')
+        )
+    {
+        my $ArticleTime = $ArticleObject->ArticleAccountedTimeGet(
+            ArticleID => $Param{ArticleID},
+        );
+        if ($ArticleTime) {
+            $Result{Time} = {
+                Label => "Time",
+                Value => $ArticleTime,
+            };
+        }
+    }
+
+    # get dynamic field config for frontend module
+    my $DynamicFieldFilter = {
+        %{ $ConfigObject->Get("Ticket::Frontend::AgentTicketZoom")->{DynamicField} || {} },
+        %{
+            $ConfigObject->Get("Ticket::Frontend::AgentTicketZoom")->{ProcessWidgetDynamicField}
+                || {}
+        },
+    };
+
+    # get the dynamic fields for article object
+    my $DynamicField = $Kernel::OM->Get('Kernel::System::DynamicField')->DynamicFieldListGet(
+        Valid       => 1,
+        ObjectType  => ['Article'],
+        FieldFilter => $DynamicFieldFilter || {},
+    );
+    my $DynamicFieldBackendObject = $Kernel::OM->Get('Kernel::System::DynamicField::Backend');
+
+    # cycle trough the activated Dynamic Fields
+    DYNAMICFIELD:
+    for my $DynamicFieldConfig ( @{$DynamicField} ) {
+        next DYNAMICFIELD if !IsHashRefWithData($DynamicFieldConfig);
+
+        my $Value = $DynamicFieldBackendObject->ValueGet(
+            DynamicFieldConfig => $DynamicFieldConfig,
+            ObjectID           => $Param{ArticleID},
+        );
+
+        next DYNAMICFIELD if !$Value;
+        next DYNAMICFIELD if $Value eq '';
+
+        # get print string for this dynamic field
+        my $ValueStrg = $DynamicFieldBackendObject->DisplayValueRender(
+            DynamicFieldConfig => $DynamicFieldConfig,
+            Value              => $Value,
+            ValueMaxChars      => $ConfigObject->Get('Ticket::Frontend::DynamicFieldsZoomMaxSizeArticle')
+                || 160,    # limit for article display
+            LayoutObject => $LayoutObject,
+        );
+
+        my $Label = $DynamicFieldConfig->{Label};
+
+        $Result{ $DynamicFieldConfig->{Name} } = {
+            Label => $Label,
+            Value => $ValueStrg->{Value},
+            Title => $ValueStrg->{Title},
+        };
+
+        if ( $ValueStrg->{Link} ) {
+            $Result{ $DynamicFieldConfig->{Name} }->{Link} = $ValueStrg->{Link};
+        }
+    }
+
+    return %Result;
+}
+
+=head1 PRIVATE FUNCTIONS
+
+=head2 _ArticleSenderImage()
+
+Get URL used for article sender image.
+
+    my $SenderImage = $ArticleBaseObject->_ArticleSenderImage(
+        Sender => 'John Doe <jdoe@example.com>',
+    );
+
+Returns:
+
+    $SenderImage = '//gravatar.com/avatar/28a58af1db24962e81212115e7cac685?s=80';
+
+=cut
+
+sub _ArticleSenderImage {
+    my ( $Self, %Param ) = @_;
+
+    my $Result = '';
+
+    return $Result if !$Param{Sender};
+
+    my $Size = 80;
+
+    # Get email address from sender field.
+    my $EmailParser = Kernel::System::EmailParser->new(
+        %{$Self},
+        Mode => 'Standalone',
+    );
+    my @Addresses = $EmailParser->SplitAddressLine( Line => $Param{Sender} );
+    if (@Addresses) {
+        my $Email = $EmailParser->GetEmailAddress( Email => $Addresses[0] );
+        if ($Email) {
+            my $DefaultIcon
+                = $Kernel::OM->Get('Kernel::Config')->Get('Frontend::Gravatar::ArticleDefaultImage') || 'mm';
+
+            # Get current user's email and compare it to the sender's email.
+            if ( $Param{UserID} ) {
+                my %CurrentUserData = $Kernel::OM->Get('Kernel::System::User')->GetUserData( UserID => $Param{UserID} );
+                if ( $Email eq $CurrentUserData{UserEmail} ) {
+                    $DefaultIcon = $Kernel::OM->Get('Kernel::Config')->Get('Frontend::Gravatar::DefaultImage') | 'mm';
+                }
+            }
+
+            $Result = '//www.gravatar.com/avatar/' . md5_hex( lc $Email ) . '?s=' . $Size . '&d=' . $DefaultIcon;
+        }
+    }
+
+    return $Result;
+}
+
+sub _ArticleModuleMeta {
+    my ( $Self, %Param ) = @_;
+
+    # Check needed stuff.
+    for my $Needed (qw(TicketID ArticleID UserID)) {
+        if ( !$Param{$Needed} ) {
+            $Kernel::OM->Get('Kernel::System::Log')->Log(
+                Priority => 'error',
+                Message  => "Need $Needed!",
+            );
+            return;
+        }
+    }
+
+    # get config object
+    my $ConfigObject = $Kernel::OM->Get('Kernel::Config');
+    my $LayoutObject = $Kernel::OM->Get('Kernel::Output::HTML::Layout');
+
+    # check whether auto article links should be used
+    return if !$ConfigObject->Get('Ticket::Frontend::ZoomCollectMeta');
+    return if !$ConfigObject->Get('Ticket::Frontend::ZoomCollectMetaFilters');
+
+    my $ArticlePlain = $LayoutObject->ArticlePreview(
+        %Param,
+        ResultType => 'plain',
+    );
+
+    my @Data;
+
+    # find words to replace
+    my %Config = %{ $ConfigObject->Get('Ticket::Frontend::ZoomCollectMetaFilters') };
+
+    FILTER:
+    for my $Filter ( values %Config ) {
+
+        my %FilterData;
+
+        # check for needed data
+        next FILTER if !$Filter->{RegExp};
+        next FILTER if !$Filter->{Meta};
+        next FILTER if !$Filter->{Meta}->{Name};
+        next FILTER if !$Filter->{Meta}->{URL};
+
+        # iterage through regular expressions and create a hash with found matches
+        my @Matches;
+        for my $RegExp ( @{ $Filter->{RegExp} } ) {
+
+            my @Count    = $RegExp =~ m{\(}gx;
+            my $Elements = scalar @Count;
+
+            if ( my @MatchData = $ArticlePlain =~ m{([\s:]$RegExp)}gxi ) {
+                my $Counter = 0;
+
+                MATCH:
+                while ( $MatchData[$Counter] ) {
+
+                    my $WholeMatchString = $MatchData[$Counter];
+                    $WholeMatchString =~ s/^\s+|\s+$//g;
+                    if ( grep { $_->{Name} eq $WholeMatchString } @Matches ) {
+                        $Counter += $Elements + 1;
+                        next MATCH;
+                    }
+
+                    my %Parts;
+                    for ( 1 .. $Elements ) {
+                        $Parts{$_} = $MatchData[ $Counter + $_ ];
+                    }
+                    $Counter += $Elements + 1;
+
+                    push @Matches, {
+                        Name  => $WholeMatchString,
+                        Parts => \%Parts,
+                    };
+                }
+            }
+        }
+
+        if ( scalar @Matches ) {
+
+            $FilterData{Name} = $Filter->{Meta}->{Name};
+
+            # iterate trough matches and build URLs from configuration
+            for my $Match (@Matches) {
+
+                my $MatchQuote = $LayoutObject->Ascii2Html( Text => $Match->{Name} );
+                my $URL        = $Filter->{Meta}->{URL};
+                my $URLPreview = $Filter->{Meta}->{URLPreview};
+
+                # replace the whole keyword
+                my $MatchLinkEncode = $LayoutObject->LinkEncode( $Match->{Name} );
+                $URL        =~ s/<MATCH>/$MatchLinkEncode/g;
+                $URLPreview =~ s/<MATCH>/$MatchLinkEncode/g;
+
+                # replace the keyword components
+                for my $Part ( sort keys %{ $Match->{Parts} || {} } ) {
+                    $MatchLinkEncode = $LayoutObject->LinkEncode( $Match->{Parts}->{$Part} );
+                    $URL        =~ s/<MATCH$Part>/$MatchLinkEncode/g;
+                    $URLPreview =~ s/<MATCH$Part>/$MatchLinkEncode/g;
+                }
+
+                push @{ $FilterData{Matches} }, {
+                    Text       => $Match->{Name},
+                    URL        => $URL,
+                    URLPreview => $URLPreview,
+                    Target     => $Filter->{Meta}->{Target} || '_blank',
+                };
+            }
+            push @Data, \%FilterData;
+        }
+    }
+
+    return @Data;
+}
+
+1;

Perl OTRS/Kernel/Output/HTML/TicketZoom/Agent/Chat.pm

@@ -0,0 +1,136 @@
+# --
+# Copyright (C) 2001-2019 OTRS AG, https://otrs.com/
+# --
+# This software comes with ABSOLUTELY NO WARRANTY. For details, see
+# the enclosed file COPYING for license information (GPL). If you
+# did not receive this file, see https://www.gnu.org/licenses/gpl-3.0.txt.
+# --
+
+package Kernel::Output::HTML::TicketZoom::Agent::Chat;
+
+use parent 'Kernel::Output::HTML::TicketZoom::Agent::Base';
+
+use strict;
+use warnings;
+
+use Kernel::System::VariableCheck qw(IsPositiveInteger);
+
+our @ObjectDependencies = (
+    'Kernel::Config',
+    'Kernel::Output::HTML::Layout',
+    'Kernel::System::CommunicationChannel',
+    'Kernel::System::Log',
+    'Kernel::System::Ticket::Article',
+    'Kernel::System::User',
+);
+
+=head2 ArticleRender()
+
+Returns article html.
+
+    my $HTML = $ArticleBaseObject->ArticleRender(
+        TicketID       => 123,   # (required)
+        ArticleID      => 123,   # (required)
+        ArticleActions => [],    # (optional)
+        UserID         => 123,   # (optional)
+    );
+
+Result:
+    $HTML = "<div>...</div>";
+
+=cut
+
+sub ArticleRender {
+    my ( $Self, %Param ) = @_;
+
+    # Check needed stuff.
+    for my $Needed (qw(TicketID ArticleID)) {
+        if ( !$Param{$Needed} ) {
+            $Kernel::OM->Get('Kernel::System::Log')->Log(
+                Priority => 'error',
+                Message  => "Need $Needed!",
+            );
+            return;
+        }
+    }
+
+    my $ConfigObject         = $Kernel::OM->Get('Kernel::Config');
+    my $LayoutObject         = $Kernel::OM->Get('Kernel::Output::HTML::Layout');
+    my $ArticleBackendObject = $Kernel::OM->Get('Kernel::System::Ticket::Article')->BackendForArticle(%Param);
+
+    my %Article = $ArticleBackendObject->ArticleGet(%Param);
+    if ( !%Article ) {
+        $Kernel::OM->Get('Kernel::System::Log')->Log(
+            Priority => 'error',
+            Message  => "Article not found (ArticleID=$Param{ArticleID})!"
+        );
+        return;
+    }
+
+    # Check if HTML should be displayed.
+    my $ShowHTML = $ConfigObject->Get('Ticket::Frontend::ZoomRichTextForce')
+        || $LayoutObject->{BrowserRichText}
+        || 0;
+
+    # Get channel specific fields
+    my %ArticleFields = $LayoutObject->ArticleFields(%Param);
+
+    # Get dynamic fields and accounted time
+    my %ArticleMetaFields = $Self->ArticleMetaFields(%Param);
+
+    # Get data from modules like Google CVE search
+    my @ArticleModuleMeta = $Self->_ArticleModuleMeta(%Param);
+
+    # Show created by string, if creator is different from admin user.
+    if ( $Article{CreateBy} > 1 ) {
+        $Article{CreateByUser} = $Kernel::OM->Get('Kernel::System::User')->UserName( UserID => $Article{CreateBy} );
+    }
+
+    my $ArticleContent = $LayoutObject->ArticlePreview(
+        TicketID   => $Param{TicketID},
+        ArticleID  => $Param{ArticleID},
+        ResultType => $ShowHTML ? 'HTML' : 'plain',
+    );
+
+    if ( !$ShowHTML ) {
+
+        # html quoting
+        $ArticleContent = $LayoutObject->Ascii2Html(
+            NewLine        => $ConfigObject->Get('DefaultViewNewLine'),
+            Text           => $ArticleContent,
+            VMax           => $ConfigObject->Get('DefaultViewLines') || 5000,
+            HTMLResultMode => 1,
+            LinkFeature    => 1,
+        );
+    }
+
+    my %CommunicationChannel = $Kernel::OM->Get('Kernel::System::CommunicationChannel')->ChannelGet(
+        ChannelID => $Article{CommunicationChannelID},
+    );
+
+    my $Content = $LayoutObject->Output(
+        TemplateFile => 'AgentTicketZoom/ArticleRender/Chat',
+        Data         => {
+            %Article,
+            ArticleFields        => \%ArticleFields,
+            ArticleMetaFields    => \%ArticleMetaFields,
+            ArticleModuleMeta    => \@ArticleModuleMeta,
+            MenuItems            => $Param{ArticleActions},
+            Body                 => $ArticleContent,
+            HTML                 => $ShowHTML,
+            CommunicationChannel => $CommunicationChannel{DisplayName},
+            ChannelIcon          => $CommunicationChannel{DisplayIcon},
+            SenderImage          => $Self->_ArticleSenderImage(
+                Sender => $ArticleFields{Sender}->{Value},
+                UserID => $Param{UserID},
+            ),
+            SenderInitials => $LayoutObject->UserInitialsGet(
+                Fullname => $ArticleFields{Sender}->{Realname},
+            ),
+        },
+    );
+
+    return $Content;
+}
+
+1;

Perl OTRS/Kernel/Output/HTML/TicketZoom/Agent/Email.pm

@@ -0,0 +1,20 @@
+# --
+# Copyright (C) 2001-2019 OTRS AG, https://otrs.com/
+# --
+# This software comes with ABSOLUTELY NO WARRANTY. For details, see
+# the enclosed file COPYING for license information (GPL). If you
+# did not receive this file, see https://www.gnu.org/licenses/gpl-3.0.txt.
+# --
+
+package Kernel::Output::HTML::TicketZoom::Agent::Email;
+
+use strict;
+use warnings;
+
+use parent 'Kernel::Output::HTML::TicketZoom::Agent::MIMEBase';
+
+our @ObjectDependencies = (
+
+);
+
+1;

Perl OTRS/Kernel/Output/HTML/TicketZoom/Agent/Internal.pm

@@ -0,0 +1,20 @@
+# --
+# Copyright (C) 2001-2019 OTRS AG, https://otrs.com/
+# --
+# This software comes with ABSOLUTELY NO WARRANTY. For details, see
+# the enclosed file COPYING for license information (GPL). If you
+# did not receive this file, see https://www.gnu.org/licenses/gpl-3.0.txt.
+# --
+
+package Kernel::Output::HTML::TicketZoom::Agent::Internal;
+
+use strict;
+use warnings;
+
+use parent 'Kernel::Output::HTML::TicketZoom::Agent::MIMEBase';
+
+our @ObjectDependencies = (
+
+);
+
+1;

Perl OTRS/Kernel/Output/HTML/TicketZoom/Agent/Invalid.pm

@@ -0,0 +1,122 @@
+# --
+# Copyright (C) 2001-2019 OTRS AG, https://otrs.com/
+# --
+# This software comes with ABSOLUTELY NO WARRANTY. For details, see
+# the enclosed file COPYING for license information (GPL). If you
+# did not receive this file, see https://www.gnu.org/licenses/gpl-3.0.txt.
+# --
+
+package Kernel::Output::HTML::TicketZoom::Agent::Invalid;
+
+use parent 'Kernel::Output::HTML::TicketZoom::Agent::Base';
+
+use strict;
+use warnings;
+
+use Kernel::System::VariableCheck qw(IsPositiveInteger);
+
+our @ObjectDependencies = (
+    'Kernel::Config',
+    'Kernel::Output::HTML::Layout',
+    'Kernel::System::CommunicationChannel',
+    'Kernel::System::Log',
+    'Kernel::System::Ticket::Article',
+    'Kernel::System::User',
+);
+
+=head2 ArticleRender()
+
+Returns invalid article HTML.
+
+    my $HTML = $ArticleBaseObject->ArticleRender(
+        TicketID       => 123,   # (required)
+        ArticleID      => 123,   # (required)
+        ArticleActions => [],    # (optional)
+    );
+
+Result:
+    $HTML = "<div>...</div>";
+
+=cut
+
+sub ArticleRender {
+    my ( $Self, %Param ) = @_;
+
+    for my $Needed (qw(TicketID ArticleID)) {
+        if ( !$Param{$Needed} ) {
+            $Kernel::OM->Get('Kernel::System::Log')->Log(
+                Priority => 'error',
+                Message  => "Need $Needed!",
+            );
+            return;
+        }
+    }
+
+    my $ConfigObject         = $Kernel::OM->Get('Kernel::Config');
+    my $LayoutObject         = $Kernel::OM->Get('Kernel::Output::HTML::Layout');
+    my $ArticleBackendObject = $Kernel::OM->Get('Kernel::System::Ticket::Article')->BackendForArticle(%Param);
+
+    my %Article = $ArticleBackendObject->ArticleGet(%Param);
+    if ( !%Article ) {
+        $Kernel::OM->Get('Kernel::System::Log')->Log(
+            Priority => 'error',
+            Message  => "Article not found (ArticleID=$Param{ArticleID})!"
+        );
+        return;
+    }
+
+    # Check if HTML should be displayed.
+    my $ShowHTML = $ConfigObject->Get('Ticket::Frontend::ZoomRichTextForce')
+        || $LayoutObject->{BrowserRichText}
+        || 0;
+
+    # Get channel specific fields
+    my %ArticleFields = $LayoutObject->ArticleFields(%Param);
+
+    # Show created by string, if creator is different from admin user.
+    if ( $Article{CreateBy} > 1 ) {
+        $Article{CreateByUser} = $Kernel::OM->Get('Kernel::System::User')->UserName( UserID => $Article{CreateBy} );
+    }
+
+    my $ArticleContent = $LayoutObject->ArticlePreview(
+        TicketID   => $Param{TicketID},
+        ArticleID  => $Param{ArticleID},
+        ResultType => $ShowHTML ? 'HTML' : 'plain',
+    );
+
+    if ( !$ShowHTML ) {
+
+        # HTML quoting.
+        $ArticleContent = $LayoutObject->Ascii2Html(
+            NewLine        => $ConfigObject->Get('DefaultViewNewLine'),
+            Text           => $ArticleContent,
+            VMax           => $ConfigObject->Get('DefaultViewLines') || 5000,
+            HTMLResultMode => 1,
+            LinkFeature    => 1,
+        );
+    }
+
+    my %CommunicationChannel = $Kernel::OM->Get('Kernel::System::CommunicationChannel')->ChannelGet(
+        ChannelID => $Article{CommunicationChannelID},
+    );
+
+    my $Content = $LayoutObject->Output(
+        TemplateFile => 'AgentTicketZoom/ArticleRender/Invalid',
+        Data         => {
+            %Article,
+            ArticleFields        => \%ArticleFields,
+            MenuItems            => $Param{ArticleActions},
+            Body                 => $ArticleContent,
+            HTML                 => $ShowHTML,
+            CommunicationChannel => $CommunicationChannel{DisplayName},
+            ChannelIcon          => $CommunicationChannel{DisplayIcon},
+            SenderInitials       => $LayoutObject->UserInitialsGet(
+                Fullname => $ArticleFields{Sender}->{Realname},
+            ),
+        },
+    );
+
+    return $Content;
+}
+
+1;

Perl OTRS/Kernel/Output/HTML/TicketZoom/Agent/MIMEBase.pm

@@ -0,0 +1,256 @@
+# --
+# Copyright (C) 2001-2019 OTRS AG, https://otrs.com/
+# --
+# This software comes with ABSOLUTELY NO WARRANTY. For details, see
+# the enclosed file COPYING for license information (GPL). If you
+# did not receive this file, see https://www.gnu.org/licenses/gpl-3.0.txt.
+# --
+
+package Kernel::Output::HTML::TicketZoom::Agent::MIMEBase;
+
+use parent 'Kernel::Output::HTML::TicketZoom::Agent::Base';
+
+use strict;
+use warnings;
+
+use Kernel::System::VariableCheck qw(IsPositiveInteger);
+use Kernel::Language qw(Translatable);
+
+our @ObjectDependencies = (
+    'Kernel::Config',
+    'Kernel::Output::HTML::Article::MIMEBase',
+    'Kernel::Output::HTML::Layout',
+    'Kernel::System::CommunicationChannel',
+    'Kernel::System::Main',
+    'Kernel::System::Log',
+    'Kernel::System::Ticket::Article',
+    'Kernel::System::User',
+);
+
+=head2 ArticleRender()
+
+Returns article html.
+
+    my $HTML = $ArticleBaseObject->ArticleRender(
+        TicketID               => 123,         # (required)
+        ArticleID              => 123,         # (required)
+        ShowBrowserLinkMessage => 1,           # (optional) Default: 0.
+        ArticleActions         => [],          # (optional)
+        UserID                 => 123,         # (optional)
+    );
+
+Result:
+    $HTML = "<div>...</div>";
+
+=cut
+
+sub ArticleRender {
+    my ( $Self, %Param ) = @_;
+
+    # Check needed stuff.
+    for my $Needed (qw(TicketID ArticleID)) {
+        if ( !$Param{$Needed} ) {
+            $Kernel::OM->Get('Kernel::System::Log')->Log(
+                Priority => 'error',
+                Message  => "Need $Needed!",
+            );
+            return;
+        }
+    }
+
+    my $ConfigObject         = $Kernel::OM->Get('Kernel::Config');
+    my $LayoutObject         = $Kernel::OM->Get('Kernel::Output::HTML::Layout');
+    my $MainObject           = $Kernel::OM->Get('Kernel::System::Main');
+    my $ArticleBackendObject = $Kernel::OM->Get('Kernel::System::Ticket::Article')->BackendForArticle(%Param);
+
+    my %Article = $ArticleBackendObject->ArticleGet(
+        %Param,
+        RealNames => 1,
+    );
+    if ( !%Article ) {
+        $Kernel::OM->Get('Kernel::System::Log')->Log(
+            Priority => 'error',
+            Message  => "Article not found (ArticleID=$Param{ArticleID})!"
+        );
+        return;
+    }
+
+    # Get channel specific fields
+    my %ArticleFields = $LayoutObject->ArticleFields(%Param);
+
+    # Get dynamic fields and accounted time
+    my %ArticleMetaFields = $Self->ArticleMetaFields(%Param);
+
+    # Get data from modules like Google CVE search
+    my @ArticleModuleMeta = $Self->_ArticleModuleMeta(%Param);
+
+    # Show created by string, if creator is different from admin user.
+    if ( $Article{CreateBy} > 1 ) {
+        $Article{CreateByUser} = $Kernel::OM->Get('Kernel::System::User')->UserName( UserID => $Article{CreateBy} );
+    }
+
+    my $RichTextEnabled = $ConfigObject->Get('Ticket::Frontend::ZoomRichTextForce')
+        || $LayoutObject->{BrowserRichText}
+        || 0;
+
+    # Show HTML if RichText is enabled and HTML attachment isn't missing.
+    my $ShowHTML         = $RichTextEnabled;
+    my $HTMLBodyAttachID = $Kernel::OM->Get('Kernel::Output::HTML::Article::MIMEBase')->HTMLBodyAttachmentIDGet(
+        %Param,
+    );
+    if ( $ShowHTML && !$HTMLBodyAttachID ) {
+        $ShowHTML = 0;
+    }
+
+    # Strip plain text attachments by default.
+    my $ExcludePlainText = 1;
+
+    # Do not strip plain text attachments if no plain text article body was found.
+    if ( $Article{Body} && $Article{Body} eq '- no text message => see attachment -' ) {
+        $ExcludePlainText = 0;
+    }
+
+    # Get attachment index (excluding body attachments).
+    my %AtmIndex = $ArticleBackendObject->ArticleAttachmentIndex(
+        ArticleID        => $Param{ArticleID},
+        ExcludePlainText => $ExcludePlainText,
+        ExcludeHTMLBody  => $RichTextEnabled,
+        ExcludeInline    => $RichTextEnabled,
+    );
+
+    my @ArticleAttachments;
+
+    # Add block for attachments.
+    if (%AtmIndex) {
+        my $Config = $ConfigObject->Get('Ticket::Frontend::ArticleAttachmentModule');
+
+        ATTACHMENT:
+        for my $FileID ( sort keys %AtmIndex ) {
+
+            my $Attachment;
+
+            # Run article attachment modules.
+            next ATTACHMENT if ref $Config ne 'HASH';
+            my %Jobs = %{$Config};
+
+            JOB:
+            for my $Job ( sort keys %Jobs ) {
+                my %File = %{ $AtmIndex{$FileID} };
+
+                # load module
+                next JOB if !$MainObject->Require( $Jobs{$Job}->{Module} );
+                my $Object = $Jobs{$Job}->{Module}->new(
+                    %{$Self},
+                    TicketID  => $Param{TicketID},
+                    ArticleID => $Param{ArticleID},
+                    UserID    => $Param{UserID} || 1,
+                );
+
+                # run module
+                my %Data = $Object->Run(
+                    File => {
+                        %File,
+                        FileID => $FileID,
+                    },
+                    TicketID => $Param{TicketID},
+                    Article  => \%Article,
+                );
+
+                if (%Data) {
+                    %File = %Data;
+                }
+
+                $File{Links} = [
+                    {
+                        Action => $File{Action},
+                        Class  => $File{Class},
+                        Link   => $File{Link},
+                        Target => $File{Target},
+                    },
+                ];
+                if ( $File{Action} && $File{Action} ne 'Download' ) {
+                    delete $File{Action};
+                    delete $File{Class};
+                    delete $File{Link};
+                    delete $File{Target};
+                }
+
+                if ($Attachment) {
+                    push @{ $Attachment->{Links} }, $File{Links}->[0];
+                }
+                else {
+                    $Attachment = \%File;
+                }
+            }
+            push @ArticleAttachments, $Attachment;
+        }
+    }
+
+    my $ArticleContent;
+
+    if ($ShowHTML) {
+        if ( $Param{ShowBrowserLinkMessage} ) {
+            $LayoutObject->Block(
+                Name => 'BrowserLinkMessage',
+            );
+        }
+    }
+    else {
+        $ArticleContent = $LayoutObject->ArticlePreview(
+            %Param,
+            ResultType => 'plain',
+        );
+
+        # html quoting
+        $ArticleContent = $LayoutObject->Ascii2Html(
+            NewLine        => $ConfigObject->Get('DefaultViewNewLine'),
+            Text           => $ArticleContent,
+            VMax           => $ConfigObject->Get('DefaultViewLines') || 5000,
+            HTMLResultMode => 1,
+            LinkFeature    => 1,
+        );
+    }
+
+    my %CommunicationChannel = $Kernel::OM->Get('Kernel::System::CommunicationChannel')->ChannelGet(
+        ChannelID => $Article{CommunicationChannelID},
+    );
+
+    if ( $CommunicationChannel{ChannelName} eq 'Email' ) {
+        my $TransmissionStatus = $ArticleBackendObject->ArticleTransmissionStatus(
+            ArticleID => $Article{ArticleID},
+        );
+        if ($TransmissionStatus) {
+            $LayoutObject->Block(
+                Name => 'TransmissionStatusMessage',
+                Data => $TransmissionStatus,
+            );
+        }
+    }
+
+    my $Content = $LayoutObject->Output(
+        TemplateFile => 'AgentTicketZoom/ArticleRender/MIMEBase',
+        Data         => {
+            %Article,
+            ArticleFields        => \%ArticleFields,
+            ArticleMetaFields    => \%ArticleMetaFields,
+            ArticleModuleMeta    => \@ArticleModuleMeta,
+            Attachments          => \@ArticleAttachments,
+            MenuItems            => $Param{ArticleActions},
+            Body                 => $ArticleContent,
+            HTML                 => $ShowHTML,
+            CommunicationChannel => $CommunicationChannel{DisplayName},
+            ChannelIcon          => $CommunicationChannel{DisplayIcon},
+            SenderImage          => $Self->_ArticleSenderImage(
+                Sender => $Article{From},
+                UserID => $Param{UserID},
+            ),
+            SenderInitials => $LayoutObject->UserInitialsGet(
+                Fullname => $Article{FromRealname},
+            ),
+        },
+    );
+
+    return $Content;
+}
+
+1;

Perl OTRS/Kernel/Output/HTML/TicketZoom/Agent/Phone.pm

@@ -0,0 +1,20 @@
+# --
+# Copyright (C) 2001-2019 OTRS AG, https://otrs.com/
+# --
+# This software comes with ABSOLUTELY NO WARRANTY. For details, see
+# the enclosed file COPYING for license information (GPL). If you
+# did not receive this file, see https://www.gnu.org/licenses/gpl-3.0.txt.
+# --
+
+package Kernel::Output::HTML::TicketZoom::Agent::Phone;
+
+use strict;
+use warnings;
+
+use parent 'Kernel::Output::HTML::TicketZoom::Agent::MIMEBase';
+
+our @ObjectDependencies = (
+
+);
+
+1;